move window by pixel

Discussion & Questions
1

since optimal layout is not longer in development I am looking for an app that does what it does (but can't find one).

optimal layout allows me to move a window up, down, left, right, a few pixels using a keyboard shortcut; I can move a window from one monitor to the other too using the same keyboard shortcut.

Can BBT do this?

I saw this thread but not sure if there is a simpler way: leftclick and drag one pixel at a time

Thank you

2

@djbbt, you could use AppleScript to move windows by one pixel at a time. I'm not sure about moving between monitors, as I only have one monitor so cannot test that.

use application "System Events"
property process : a reference to (the first process where it is frontmost)
--------------------------------------------------------------------------------
property |𝚫| : 1 -- The number of pixels by which to move the window
--------------------------------------------------------------------------------
--IMPLEMENTATION:
tell the frontWindow to move right_
--OR:
--tell the frontWindow to move left_
--tell the frontWindow to move up_
--tell the frontWindow to move down_
--------------------------------------------------------------------------------
--SCRIPT OBJECTS & HANDLERS:
script frontWindow
	property window : a reference to window 1 of my process
	
	to move direction
		local direction
		
		script
			property fn_ : direction
		end script
		
		result's fn:(a reference to the position ¬
			of (a reference to my window))
	end move
end script

on up:position
	local position
	global |𝚫|
	
	set {x, y} to position's contents
	set contents of position to {x, y - |𝚫|}
	{x, y}
end up:
on down:position
	local position
	global |𝚫|
	
	set {x, y} to position's contents
	set contents of position to {x, y + |𝚫|}
	{x, y}
end down:
on |left|:position
	local position
	global |𝚫|
	
	set {x, y} to position's contents
	set contents of position to {x - |𝚫|, y}
	{x, y}
end |left|:
on |right|:position
	local position
	global |𝚫|
	
	set {x, y} to position's contents
	set contents of position to {x + |𝚫|, y}
	{x, y}
end |right|:
---------------------------------------------------------------------------❮END❯
3

thanks for the suggestion! I found out that Moom does exactly this so I will use Moom. Thank you again.